魔獸世界戰士給個宏 切換:狂暴姿態+攔截+魯莽+戰鬥姿態
- 2022-10-14
來自NGA的支援。。。ZS宏基本全了~
這裡列出tbc裡最常見實用的一些戰士宏。由於我用的是英文版,寫一些技能和物品的中文名稱可能會有差錯,不過意思應該是明白的。
如果一個宏不工作:
1。先看看是否有中文名不正確,以及是否有全形標點符號。
2。再試著在遊戲裡打一遍而不要直接複製粘帖。
對戰士來說,tbc的宏有兩個最明顯的變化:
1。判斷語句失效。類似“如果……。那麼……。否則……”的語句一概不能再用。
具體舉例如目標20%以下放斬殺,否則放致死的宏不行了,又或者45怒以上點亮英勇,否則用致死,等等
2。包含一大堆 /施放 的宏不能再用。比如:
/cast 盾牌猛擊
/cast 復仇
/cast 破甲
/cast 盾牌格擋
這個傻瓜宏如今行不通。在舊的wow裡,這個宏如果盾猛不能用,那麼程式將跳過它並檢查復仇,如果不行就看破甲,以此類推,每按一次至少都會有一個命令被執行。但tbc裡一旦某一步不能用,程式將卡在這裡,後面所有的觸發同種公共cd的技能都被華麗地無視了,僅有少數“點亮”型技能能夠繼續被執行,如英勇和順劈。所以
/cast 壓制
/stopcasting
/cast 致死打擊
永遠放不出致死。而
/cast 壓制
/stopcasting
/cast 英勇打擊
可以,因為英勇並不佔用公共cd。此外
/cast 壓制
/stopcasting
/cast 狂暴姿態
可以。因為姿態切換有著自己的獨立1秒的公共cd。最後是
/cast 衝鋒
/stopcasting
/cast 英勇
/stopcasting
/cast 狂暴姿態
是可行的。因為衝鋒/切姿態是互相獨立的cd,而英勇不屬於任何一種,因此一鍵可以做這三件事。這是經典衝鋒宏能夠再現的基礎。
其實有兩種方法可以部分繞過這些限制,一是施放序列/castsequence,另一個是隨機施放/castrandom,但效果很不好,不如不用,不提也罷
以上是關於戰士的宏的簡單的介紹,希望看了的人對哪些宏能用,哪些要被淘汰心裡有底。也希望大家能夠舉一反三,很多時候不少小宏都是同一型別的變體而已。
0。開始攻擊
/startattack
這簡單的一行能讓你開始攻擊目標,並且怎麼按都不會停止。比如你可以將其跟致死合用:
/startattack
/cast 致死打擊
這樣不管有沒有怒放致死,按這個宏都會讓你開始攻擊。
如果你習慣於單獨將其作為一個按鈕,那麼加上一行:
#show 攻擊
/startattack
1。衝鋒/攔截/斷筋/切姿態
#show [stance:1]衝鋒; [stance:3]攔截
/startattack
/cast 斷筋
/stopcasting
/cast [nocombat,stance:1] 衝鋒; [nocombat,nostance:1] 戰鬥姿態; [combat,nostance:3] 狂暴姿態; [combat,stance:3] 攔截
鑑於不少人反映切狂暴有時會誤事,把上面加粗部分刪除就能去掉這宏切狂暴姿態的能力
戰鬥外衝鋒,如果不在戰鬥姿態則會切過去,然後再按一下
戰鬥中攔截,如果不在狂暴姿態則會切過去,然後再按一下
任何情況下近身後斷筋
戰鬥姿態下顯示衝鋒的冷卻,狂暴姿態下顯示攔截的冷卻
在馬上則自動下馬+衝鋒,只需按一次
與舊的宏系統能做的事情相比,少了一個判斷如果怒氣不夠10則先血怒再攔截的功能
雖然省事且可靠,但從技巧上講,斷筋最好還是在快捷欄上佔獨立的位置。如果想將衝鋒攔截和別的技能繫結,把斷筋改成那個技能名稱就行
還有就是別在空中亂按這個。。。。
這個宏在15樓有進一步細化,不過一般用不到。
2。投擲/開槍/射箭 (感謝65,104,126樓)
/cast [equipped:投擲武器] 投擲; 射擊
/equip [equipped:弓/十字弓]箭頭名稱; [equipped:槍]子彈名稱
一鍵搞定任何遠端武器的使用。弓/十字弓/槍把我忘了中文版是不是這麼寫,按K檢視一下就可
3。順劈
/script SetCVar(“targetNearestDistance”,5)
/targetenemy
/cast 順劈斬
/startattack
/script SetCVar(“targetNearestDistance”,41) 第1行和第5行是設定最小自動選擇目標的距離。
原始的順劈是這樣的:
如果你當前沒有選中目標,按下順劈技能,系統會自動選擇前方最近的一個目標,不管是否在近戰距離內。
如果你當前選中了目標,那麼不管怎麼按都不會改變目標,就算目標在很遠的地方而你鼻子底下就有另一個目標也好。
那麼戰場裡有時會遇到這樣的情況:你怒氣足夠,目標A和B都在5碼內。你選中A並按下順劈,但在下一次攻擊出手前A跑出了近戰距離,而B仍在近戰範圍內。這時你得手動切至B——這個宏就是替你做了這事:永遠選擇離自己5碼內的任意目標來順劈。
這聽起來有點多餘,但實戰中經常就是那麼手動切換的一點延遲讓A逃出了B的近戰範圍。如果人再多點,場面再混亂點,B是個侏儒然後還有賊不時暈你等等等等更是如此。
4。雙黃
/cast 毀滅打擊
/stopcasting
/cast 英勇打擊
防戰的洩怒宏。而在剛開始5破前也能利用公共cd來跳過毀滅,當純粹的英勇用
與此結構類似的有:
#show 復仇
/cast 復仇
/stopcasting
/cast 盾牌格擋
5。坐騎/斬殺
/cast [combat] 斬殺
/use [modifier:shift,nocombat,outdoors,flyable] 飛行坐騎物品名稱1; [nocombat,outdoors,flyable] 飛行坐騎物品名稱2
/use [nocombat,outdoors,noflyable] 地面坐騎物品名稱
/dismount [mounted]
如果人物在戰鬥狀態,那麼這個按鈕是斬殺——-包括圖示在內。
如果人物在非戰鬥狀態且在外域,那麼用飛行坐騎;按住shift點選則是用另一種飛行坐騎,適合平時騎魚片採集,在集合石前則騎龍顯擺的人
如果在老世界,則用千金馬。——所有圖示自動變成相應坐騎的。
這個看起來比較古怪的宏事實上是我最滿意的宏之一,tbc鍵位嚴重短缺,坐騎這東西給快捷鍵有點可惜,不給的話又不怎麼方便,何況2種。。。。。所以跟斬殺這種使用條件區分得非常明顯的東西結合起來,用到現在無任何瑕疵
6。法術反射
/cast [equipped:盾牌] 法術反射
/equip [stance:1/2] 單手武器名稱
/equip [stance:1/2,noequipped:盾牌] 盾牌名稱
如果裝備了盾就用反射,否則先裝上劍盾再用反射,多按一次
7。切換姿態+換武器
防禦:
#show 防禦姿態
/equip [stance:2,noequipped:單手劍] 單手武器名稱
/equip [stance:2,noequipped:盾牌] 盾牌名稱
/cast 防禦姿態
去掉方括號和其中的內容可實現按一次就切換姿態+武器,否則按兩次
第二行的“單手劍”可以是其他單手武器型別,對應你不常見的、特殊場合下使用的tank武器的型別。
比如說,一般不拿風劍去頂雙子,要換上個……。混亂吧。那麼第二行就是:
/equip [stance:2,noequipped:單手斧] 風劍名稱
如果你拿的是非單手斧武器,那麼這會使你換上風劍;如果你拿的是單手斧(準備頂雙子了),那麼就不會給你換風劍。如果你已經持著風劍,這行也不會做任何事。
(拿混亂舉例是為了說明型別,那麼慢的東西不適合tank)
第一行的#show是為了保證這個宏看上去和防禦姿態的圖示一模一樣……。不加這一行,防禦姿態下這個圖示周圍一圈並不會變亮
狂暴:
#show 狂暴姿態
/equip [stance:3,noequipped:雙手斧] 武器名稱
/cast 狂暴姿態
同上
戰鬥:
#show 戰鬥姿態
/equip [stance:1] 武器名稱
/cast [stance:1] 壓制; 戰鬥姿態
第二行去掉方括號內的限制只是為了說明這也可以,當然也能按前兩個那樣加上
第三行裡順路加入壓制,不加也沒所謂。如果不能放壓制,姿態還是照切。
換雙持武器:
/equipslot 16 主手武器名稱
/equipslot 17 副手武器名稱
雙手武器和劍盾互換,不包括切姿態:
/equip [noequipped:單手劍] 單手武器名稱
/equip [noequipped:盾牌] 盾牌名稱
/equip [noequipped:雙手斧] 雙手武器名稱
第一行的劍和第三行的斧按具體情況替換成自己用的武器型別
8。破膽+停止攻擊
#showtooltip 破膽怒吼
/cast 破膽怒吼
/stopattack
第一行可不要,只是給這宏加上滑鼠移上去後的破膽技能提示。也可加入繃帶的使用,在以上三行後面接上這兩句:
/stopcasting
/use [target=player] (繃帶名)
但這麼綁不太靈活,確保你破膽時不處於公共cd中,否則可能浪費繃帶機會
9。援護
#showtooltip 援護
/cast [help] 援護; [target=targettarget, help] 援護
/startattack [target=harm]
如果目標是友善的那麼援護;如果目標是敵對,那麼對其目標援護
總之就是不用切目標就能第一時間援護
10。farm宏
#showtooltip [stance:1/2]雷霆一擊; [stance:3]乘勝追擊
/cast [modifier:alt]乘勝追擊; [stance:1] 雷霆一擊
/stopcasting
/cast [nomodifier, stance:1] 狂暴姿態
/cast [stance:3] 乘勝追擊
這就是不太有普遍性的宏了,因為這個追擊顯然也能在戰鬥姿態下用
然而2個觸發公共cd的技能是不能連著寫的,因此要靠姿態繞過這限制……。
這個也可以改造成小副本用的tank開怪宏,很省心:
#showtooltip [stance:1]挫志怒吼; [stance:2]雷霆一擊
/cast [stance:1] 挫志怒吼
/stopcasting
/cast [stance:1] 防禦姿態
/cast [stance:2] 雷霆一擊
11。壓制宏
壓制現在有兩種實現方式。
第一是和姿態切換整合:
#show 戰鬥姿態
/cast [stance:1] 壓制; 戰鬥姿態
用這個宏來切換戰鬥姿態,切過來後能壓就壓,不能也沒副作用,猛按就行。省一個格子
第二是
#show 壓制
/castsequence reset=4 壓制, 狂暴姿態
放了壓制後再點直接切回狂暴。如果壓制不亮那麼不會切,如果壓制打出去但被格擋招架未命中了,仍然會切狂暴。
如果你在第二技能欄,也就是不隨姿態而變化的那些欄上有空餘位置也可以這麼寫:
#show 壓制
/castsequence reset=4 戰鬥姿態, 壓制, 狂暴姿態
壓制亮不亮都會切戰鬥,然而如果不能用的話就切不回狂暴了。
/cast [stance:1/2]狂暴姿態;魯莽
/cast [stance:3]攔截
/stopcasting
/cast 戰鬥姿態
/startattack
經測試可用,但是我本人並不建議在一個宏裡放這麼多技能。
這個宏如果按多了還是會在戰鬥姿態和狂暴姿態來回切換,看樓主自己把握了。
比較提倡的是三種姿態設三個不同的按鍵,我自己用的就是Z X C
或者一個鍵在戰鬥姿態和狂暴姿態之間切換,一個鍵切防禦姿態,然後魯莽和攔截覺得有必要可以做到一個宏裡。
首先要說的是 切換姿態要1秒的公共CD 釋放技能要1。5秒的公共CD
也就是說 這些東西你點一下這個宏是不能完成的 需要按多次
馬上問題就出來了 真正在戰鬥中 你會很清楚的分析出自己已經按了多少下麼
我自己以前做了個宏 切防禦姿態換盾開盾牆然後切戰鬥姿態換回雙手武器 保命用的 尤其是主母被點名這種
結果發現自己總是按太多下了 NND又切回防御姿態把盾背上了 後來就把這個宏中的切回戰鬥姿態換回雙手武器給刪了 另做了個宏實現這個功能
/cast 狂暴姿態
/stopcasting
/cast 攔截
/stopcasting
/cast 魯莽
/stopcasting
/cast 戰鬥姿態
試試看,不行再說